;|
C2D.LSP - (c) 2003 Tee Square Graphics
  Converts selected CIRCLE objects to circular closed
  LWPOLYLINE ("DONUT") objects.
|;

(defun C:C2D (/ ss n cir ent cen rad ltp clr)
  (while (not (setq ss (ssget '((0 . "CIRCLE"))))))
  (setq n (1- (sslength ss)))
  (while (>= n 0)
    (setq cir (ssname ss n)
          ent (entget cir)
          cen (cdr (assoc 10 ent))
          rad (cdr (assoc 40 ent))
          ltp (assoc 6 ent)
          clr (assoc 62 ent)
          n (1- n)
    );;setq
    (entmake
      (list
        '(0 . "LWPOLYLINE")
        '(100 . "AcDbEntity")
        '(100 . "AcDbPolyline")
        (assoc 8 ent)
        '(90 . 2)
        '(70 . 129)
        (cons 10 (polar cen 0 rad))
        '(42 . 1)
        (cons 10 (polar cen pi rad))
        '(42 . 1)
        (if ltp ltp '(6 . "BYLAYER"))
        (if clr clr '(62 . 256))
      );;list
    );;entmake
    (entdel cir)
    (princ)
  );;while
  (alert
    (strcat
      (itoa (sslength ss))
      " CIRCLE objects converted to closed LWPOLYLINE objects."
    );;strcat
  );;alert
  (princ)
)
(alert 
  (strcat
    "CIR2POLY.LSP (c) 2003 Tee Square Graphics\n\n"
    "         Type C2D to begin."
  )
)