;|
************************************************************************
GLT.LSP - (c) 1998 Tee Square Graphics

Global Linetype Changer for AutoCAD R14. Changes all objects and layer
  definitions of a selected linetype to a different one of user's choice.

  (load "GLT") to load, GLT<enter> to run.
************************************************************************
|;

(defun C:GLT (/ clt cmd old ent ltp lyr new ss col)
  (command "_.undo" "_be")
  (setq clt (getvar "celtype")
        cmd (getvar "cmdecho")
        old (entsel "\nPick Object of LineType to change: ")
        ent (entget (car old))
        ltp (cdr (assoc 6 ent))
        lyr (cdr (assoc 8 ent)))
  (if (null ltp)
    (setq ltp (cdr (assoc 6 (tblsearch "layer" lyr)))))
  (setq new (progn (initdia)(command "_.linetype")(getvar "celtype"))
        ss (ssget "x" (list (cons 6 ltp)))
        lyr (tblnext "layer" T))
  (if ss
    (command "_.chprop" ss "" "_lt" new ""))
  (while lyr
    (setq ent (entget (tblobjname "layer" (cdr (assoc 2 lyr))))
          lyr (tblnext "layer"))
    (if (= (cdr (setq col (assoc 6 ent))) ltp)
      (progn
        (setq ent (subst (cons 6 new) col ent))
        (entmod ent))))
  (setvar "cmdecho" cmd)
  (setvar "celtype" clt)
  (command "_.regen"
           "_.undo" "_e")
  (princ)
)
(alert (strcat
  "** GLT.LSP - (c) 1998 Tee Square Graphics **\n\n"
  "Global LineType Changer (Objects and Layers)\n"
  "                Type GLT<enter> to start."))
(princ)